home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 2: Applications / Linux Cubed Series 2 - Applications.iso / editors / emacs / xemacs / xemacs-1.006 / xemacs-1 / lib / xemacs-19.13 / lisp / utils / finder.el < prev    next >
Encoding:
Text File  |  1995-05-26  |  13.3 KB  |  389 lines
  1. ;;; finder.el --- topic & keyword-based code finder
  2.  
  3. ;; Copyright (C) 1992 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
  6. ;; Created: 16 Jun 1992
  7. ;; Version: 1.0
  8. ;; Keywords: help
  9. ;; X-Modified-by: Bob Weiner <weiner@mot.com>, 4/18/95, to include Lisp
  10. ;;    library directory names in finder-program-info, for fast display of
  11. ;;    Lisp libraries and associated commentaries.  Added {v}, finder-view,
  12. ;;    and {e}, finder-edit commands for displaying libraries.
  13. ;;    
  14. ;;    Added user variable, 'finder-abbreviate-directory-list', used to
  15. ;;    abbreviate directories before they are saved to finder-program-info.
  16. ;;    Such relative directories can be portable from one Emacs installation
  17. ;;    to another.  Default value is based upon the value of Emacs'
  18. ;;      data-directory variable.
  19.  
  20. ;; This file is part of XEmacs.
  21.  
  22. ;; XEmacs is free software; you can redistribute it and/or modify it
  23. ;; under the terms of the GNU General Public License as published by
  24. ;; the Free Software Foundation; either version 2, or (at your option)
  25. ;; any later version.
  26.  
  27. ;; XEmacs is distributed in the hope that it will be useful, but
  28. ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  29. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30. ;; General Public License for more details.
  31.  
  32. ;; You should have received a copy of the GNU General Public License
  33. ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  34. ;; Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  35.  
  36. ;;; Synched up with: FSF 19.29.
  37.  
  38. ;;; Commentary:
  39.  
  40. ;; This mode uses the Keywords library header to provide code-finding
  41. ;; services by keyword.
  42. ;;
  43. ;; Things to do:
  44. ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  45. ;; there doesn't seem to be any way to get completing-read to exit on
  46. ;; an EOL with no substring pending, which is what we'd want to end the loop.
  47. ;;    2. Search by string in synopsis line?
  48. ;;    3. Function to check finder-package-info for unknown keywords.
  49.  
  50. ;;; Code:
  51.  
  52. (require 'lisp-mnt)
  53. (require 'finder-inf)
  54. (require 'picture)
  55. (require 'mode-motion)
  56.  
  57. (defvar finder-emacs-root-directory
  58.   (file-name-directory (directory-file-name data-directory))
  59.   "Root directory of current emacs tree.")
  60.  
  61. (defvar finder-abbreviate-directory-list
  62.   (list finder-emacs-root-directory)
  63.   "*List of directory roots to remove from finder-package-info directory entries.
  64. The first element in the list is used when expanding relative package
  65. directories to view or extract information from package source code.")
  66.  
  67. (defvar finder-file-regexp "\\.el$"
  68.   "Regexp which matches file names but not Emacs Lisp finder keywords.")
  69.  
  70. ;; Local variable in finder buffer.
  71. (defvar finder-headmark)
  72.  
  73. (defvar finder-known-keywords
  74.   '(
  75.     (abbrev    . "abbreviation handling, typing shortcuts, macros")
  76.     (bib    . "code related to the `bib' bibliography processor")
  77.     (c        . "C, C++, and Objective-C language support")
  78.     (calendar    . "calendar and time management support")
  79.     (comm    . "communications, networking, remote access to files")
  80.     (data    . "support editing files of data")
  81.     (debugging    . "support for debugging programs")
  82.     (docs    . "support for Emacs documentation")
  83.     (emulations    . "emulations of other editors")
  84.     (extensions    . "Emacs Lisp language extensions")
  85.     (faces    . "support for multiple fonts")
  86.     (frames    . "support for Emacs frames and windows")
  87.     (games    . "games, jokes and amusements")
  88.     (hardware    . "support for interfacing with exotic hardware")
  89.     (help    . "support for on-line help systems")
  90.     (hypermedia    . "support for links between text or other media types")
  91.     (i18n    . "internationalization and alternate character-set support")
  92.     (internal    . "code for Emacs internals, build process, defaults")
  93.     (languages    . "specialized modes for editing programming languages")
  94.     (lisp    . "Lisp support, including Emacs Lisp")
  95.     (local    . "code local to your site")
  96.     (maint    . "maintenance aids for the Emacs development group")
  97.     (mail    . "modes for electronic-mail handling")
  98.     (matching    . "various sorts of searching and matching")
  99.     (mouse    . "mouse support")
  100.     (news    . "support for netnews reading and posting")
  101.     (oop    . "support for object-oriented programming")
  102.     (outlines    . "support for hierarchical outlining")
  103.     (processes    . "process, subshell, compilation, and job control support")
  104.     (terminals    . "support for terminal types")
  105.     (tex    . "code related to the TeX formatter")
  106.     (tools    . "programming tools")
  107.     (unix    . "front-ends/assistants for, or emulators of, UNIX features")
  108.     (vms    . "support code for vms")
  109.     (wp        . "word processing")
  110.     ))
  111.  
  112. (defvar finder-mode-map nil)
  113. (or finder-mode-map
  114.     (let ((map (make-sparse-keymap)))
  115.       (define-key map " "    'finder-select)
  116.       (define-key map "f"    'finder-select)
  117.       (define-key map "\C-m"    'finder-select)
  118.       (define-key map "e"    'finder-edit)
  119.       (define-key map "v"    'finder-view)
  120.       (define-key map "?"    'finder-summary)
  121.       (define-key map "q"    'finder-exit)
  122.       (define-key map "d"    'finder-list-keywords)
  123.       (define-key map [button2]    'finder-mouse-select)
  124.       (setq finder-mode-map map)))
  125.  
  126.  
  127. ;;; Code for regenerating the keyword list.
  128.  
  129. (defvar finder-package-info nil
  130.   "Assoc list mapping file names to description & keyword lists.")
  131.  
  132. (defvar finder-compile-keywords-quiet nil
  133.   "If non-nil finder-compile-keywords will not print any messages.")
  134.  
  135. (defun finder-compile-keywords (&rest dirs)
  136.   "Regenerate the keywords association list into the file `finder-inf.el'.
  137. Optional arguments are a list of Emacs Lisp directories to compile from; no
  138. arguments compiles from `load-path'."
  139.   (save-excursion
  140.     (find-file "finder-inf.el")
  141.     (let ((processed nil)
  142.       (directory-abbrev-alist
  143.        (append
  144.         (mapcar (function (lambda (dir) (cons dir "")))
  145.             finder-abbreviate-directory-list)
  146.         directory-abbrev-alist))
  147.       (using-load-path))
  148.       (or dirs (setq dirs load-path))
  149.       (setq using-load-path (equal dirs load-path))
  150.       (erase-buffer)
  151.       (insert ";;; finder-inf.el --- keyword-to-package mapping\n")
  152.       (insert ";; Keywords: help\n")
  153.       (insert ";;; Commentary:\n")
  154.       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
  155.       (insert ";;; Code:\n")
  156.       (insert "\n(setq finder-package-info '(\n")
  157.       (mapcar
  158.        (function
  159.     (lambda (d)
  160.       (mapcar
  161.        (function
  162.         (lambda (f) 
  163.           (if (not (member f processed))
  164.           (let (summary keystart keywords)
  165.             (setq processed (cons f processed))
  166.             (if (not finder-compile-keywords-quiet)
  167.             (message "Processing %s ..." f))
  168.             (save-excursion
  169.               (set-buffer (get-buffer-create "*finder-scratch*"))
  170.               (buffer-disable-undo (current-buffer))
  171.               (erase-buffer)
  172.               (insert-file-contents (expand-file-name f d))
  173.               (setq summary  (lm-synopsis)
  174.                 keywords (lm-keywords)))
  175.             (if (not summary)
  176.             nil
  177.               (insert (format "    (\"%s\"\n        " f))
  178.               (prin1 summary (current-buffer))
  179.               (insert "\n        ")
  180.               (setq keystart (point))
  181.               (insert (if keywords (format "(%s)" keywords) "nil"))
  182.               (subst-char-in-region keystart (point) ?, ? )
  183.               (insert "\n        ")
  184.               (prin1 (abbreviate-file-name d) (current-buffer))
  185.               (insert ")\n"))))))
  186.        ;;
  187.        ;; Skip null, non-existent or relative pathnames, e.g. "./", if
  188.        ;; using load-path, so that they do not interfere with a scan of
  189.        ;; library directories only.
  190.        (if (and using-load-path
  191.             (not (and d (file-name-absolute-p d) (file-exists-p d))))
  192.            nil
  193.          (setq d (file-name-as-directory (or d ".")))
  194.          (directory-files d nil "^[^=].*\\.el$")))))
  195.        dirs)
  196.       (insert "))\n\n(provide 'finder-inf)\n\n;;; finder-inf.el ends here\n")
  197.       (kill-buffer "*finder-scratch*")
  198.       (eval-current-buffer) ;; So we get the new keyword list immediately
  199.       (basic-save-buffer))))
  200.  
  201. ;;; Now the retrieval code
  202.  
  203. (defun finder-list-keywords ()
  204.   "Display descriptions of the keywords in the Finder buffer."
  205.   (interactive)
  206.   (setq buffer-read-only nil)
  207.   (erase-buffer)
  208.   (mapcar
  209.    (function (lambda (assoc)
  210.            (let ((keyword (car assoc)))
  211.          (insert (symbol-name keyword))
  212.          (insert-at-column 14 (concat (cdr assoc) "\n"))
  213.          (cons (symbol-name keyword) keyword))))
  214.    finder-known-keywords)
  215.   (goto-char (point-min))
  216.   (setq finder-headmark (point))
  217.   (setq buffer-read-only t)
  218.   (set-buffer-modified-p nil)
  219.   (if (not (one-window-p))
  220.       (balance-windows))
  221.   (finder-summary))
  222.  
  223. (defun finder-list-matches (key)
  224.   (setq buffer-read-only nil)
  225.   (erase-buffer)
  226.   (let ((id (intern key)))
  227.     (insert
  228.      "The following packages match the keyword `" key "':\n\n")
  229.     (setq finder-headmark (point))
  230.     (mapcar
  231.      (function (lambda (x)
  232.          (if (memq id (car (cdr (cdr x))))
  233.              (progn
  234.                (insert (car x))
  235.                (insert-at-column 16
  236.                      (concat (car (cdr x)) "\n"))
  237.                ))
  238.          ))
  239.      finder-package-info)
  240.     (goto-char (point-min))
  241.     (forward-line)
  242.     (setq buffer-read-only t)
  243.     (set-buffer-modified-p nil)
  244.     (shrink-window-if-larger-than-buffer)
  245.     (finder-summary)))
  246.  
  247. ;; Return full pathname for FILE from finder-package-info
  248. ;; or by searching for library in load-path.
  249. (defun finder-find-library (file)
  250.   (let ((dir (nth 3 (assoc file finder-package-info)))
  251.     (path))
  252.     (if dir
  253.     (setq path (expand-file-name
  254.             file
  255.             ;; Dir may be relative, in which case, we first expand it
  256.             ;; relative to the first element of
  257.             ;; finder-abbreviate-directory-list or to the local emacs
  258.             ;; root directory.
  259.             (expand-file-name
  260.              dir (or (car finder-abbreviate-directory-list)
  261.                  finder-emacs-root-directory)))))
  262.     (if (and path (file-exists-p path))
  263.     path
  264.       (finder-find-library-in-load-path file))))
  265.  
  266. ;; Search for a file named FILE the same way `load' would search.
  267. (defun finder-find-library-in-load-path (file)
  268.   (if (file-name-absolute-p file)
  269.       file
  270.     (let ((dirs load-path)
  271.       found)
  272.       (while (and dirs (not found))
  273.     (if (file-exists-p (expand-file-name (concat file ".el") (car dirs)))
  274.         (setq found (expand-file-name file (car dirs)))
  275.       (if (file-exists-p (expand-file-name file (car dirs)))
  276.           (setq found (expand-file-name file (car dirs)))))
  277.     (setq dirs (cdr dirs)))
  278.       found)))
  279.  
  280. (defun finder-commentary (file)
  281.   (interactive)
  282.   (let* ((str (lm-commentary (finder-find-library file))))
  283.     (if (null str)
  284.     (error "Can't find any Commentary section"))
  285.     (pop-to-buffer "*Finder*")
  286.     (setq buffer-read-only nil
  287.       mode-motion-hook 'mode-motion-highlight-line)
  288.     (erase-buffer)
  289.     (insert str)
  290.     (goto-char (point-min))
  291.     (delete-blank-lines)
  292.     (goto-char (point-max))
  293.     (delete-blank-lines)
  294.     (goto-char (point-min))
  295.     (while (re-search-forward "^;+ ?" nil t)
  296.       (replace-match "" nil nil))
  297.     (goto-char (point-min))
  298.     (setq buffer-read-only t)
  299.     (set-buffer-modified-p nil)
  300.     (shrink-window-if-larger-than-buffer)
  301.     (finder-summary)
  302.     ))
  303.  
  304. (defun finder-current-item ()
  305.   (if (and finder-headmark (< (point) finder-headmark))
  306.       (error "No keyword or filename on this line")
  307.     (save-excursion
  308.       (beginning-of-line)
  309.       (current-word))))
  310.  
  311. (defun finder-edit ()
  312.   (interactive)
  313.   (let ((entry (finder-current-item)))
  314.     (if (string-match finder-file-regexp entry)
  315.     (let ((path (finder-find-library entry)))
  316.       (if path
  317.           (find-file-other-window path)
  318.         (error "Can't find Emacs Lisp library: '%s'" entry)))
  319.       ;; a finder keyword
  320.       (error "Finder-edit works on Emacs Lisp libraries only"))))
  321.  
  322. (defun finder-view ()
  323.   (interactive)
  324.   (let ((entry (finder-current-item)))
  325.     (if (string-match finder-file-regexp entry)
  326.     (let ((path (finder-find-library entry)))
  327.       (if path
  328.           (view-file-other-window path)
  329.         (error "Can't find Emacs Lisp library: '%s'" entry)))
  330.       ;; a finder keyword
  331.       (error "Finder-view works on Emacs Lisp libraries only"))))
  332.  
  333. (defun finder-select ()
  334.   (interactive)
  335.   (let ((key (finder-current-item)))
  336.     (if (string-match finder-file-regexp key)
  337.     (finder-commentary key)
  338.       (finder-list-matches key))))
  339.  
  340. (defun finder-mouse-select (ev)
  341.   (interactive "e")
  342.   (goto-char (event-point ev))
  343.   (finder-select))
  344.  
  345. (defun finder-by-keyword ()
  346.   "Find packages matching a given keyword."
  347.   (interactive)
  348.   (finder-mode)
  349.   (finder-list-keywords))
  350.  
  351. (defun finder-mode ()
  352.   "Major mode for browsing package documentation.
  353. \\<finder-mode-map>
  354. \\[finder-select]    more help for the item on the current line
  355. \\[finder-edit] edit Lisp library in another window
  356. \\[finder-view] view Lisp library in another window
  357. \\[finder-exit]    exit Finder mode and kill the Finder buffer.
  358. "
  359.   (interactive)
  360.   (pop-to-buffer "*Finder*")
  361.   (setq buffer-read-only nil
  362.     mode-motion-hook 'mode-motion-highlight-line)
  363.   (erase-buffer)
  364.   (use-local-map finder-mode-map)
  365.   (set-syntax-table emacs-lisp-mode-syntax-table)
  366.   (setq mode-name "Finder")
  367.   (setq major-mode 'finder-mode)
  368.   (make-local-variable 'finder-headmark)
  369.   (setq finder-headmark nil)
  370. )
  371.  
  372. (defun finder-summary ()
  373.   "Summarize basic Finder commands."
  374.   (interactive)
  375.   (message
  376.    (substitute-command-keys
  377.     "\\<finder-mode-map>\\[finder-select] = select, \\[finder-list-keywords] = keywords, \\[finder-edit] = edit, \\[finder-view] = view, \\[finder-exit] = quit, \\[finder-summary] = help")))
  378.  
  379. (defun finder-exit ()
  380.   "Exit Finder mode and kill the buffer"
  381.   (interactive)
  382.   (or (one-window-p t 0)
  383.       (delete-window))
  384.   (kill-buffer "*Finder*"))
  385.  
  386. (provide 'finder)
  387.  
  388. ;;; finder.el ends here
  389.